pdm使用经验

一. 去掉图表中的网格底线

Tools -> Dispaly Preferences -> General Settings ->
General标签 -> Diagram ->
取消勾选Show page delimiter，
点击OK，

二．创建模型

操作：file–>new Model…

快捷键：ctrl+n

常用的以下两种：

1.概念模型(conceptual Data Model)

   选择categories-->information-->conceptual Data-->ok创建概念模型
1

2.物理模型(Physical DataModel)

   选择categories-->information-->Physical Data-->ok创建物理模型
1

二．将概念模型转换成物理模型

操作：Tools–>GeneratePhysical Data Model

快捷键：ctrl+shift+p

三，显示Comment描述字段

如果要显示Comment描述字段的话，我们需要双击表格，然后进入Columns选项页，点击Customize Columns and Filter按钮，然后勾选Comment即可，如图：

当我们勾选完Comment并保存后，在Table Properties窗口Columns选项卡页中看到Comment了，如图：

但是，保存后回到设计视图，仍没有看到Comment注释信息，这样非常不便我们设计

此时，我们在工具栏找到模型->Extensions按钮，如图：

在打开的 List of Extensions 对话框中新建一个，然后点击属性按钮，如图：

在Profile右键，点击Add Metaclasses，如图：

选中Column，然后点击OK，如图：

然后选中Column，右键选择 New -> Extended Attribute，如图：

Name一个名字（例如 AttributeComment ），dataType选择String，选中 Computer、Read only
注意：名字不能用 Comment，因为这是内置名字，用了会提示你重名，如图：

切换到Get Method Script tab 将 %Get% = “” 改为 %Get% = Rtf2Ascii (obj.Comment)，如图：

确定保存，回到视图界面，在工具栏找到 工具 -> 显示首选项，如图：

依次点击 Table->Advanced，如图：

选中 Columns，然后在 List Columns 右侧，点击 Select 按钮，如图：

找到前面所设置的 AttributeComment ，勾选并保存，如图：

回到视图界面，这时table就已经能显示出Comment字段了，如图：

四，批量更新name，code，表名值为中文

工具，图中选项运行修改代码程序

选中要运行的vbs文件，点击RUN
VBS脚本

'******************************************************************************
'* File:     comment2code.vbs
'* Purpose: 在PowerDesigner的PDM图形窗口中显示数据列的中文注释
'* Title:    将字段的comment赋值到字段的code中
'* Category: 打开物理模型，运行本脚本（Ctrl+Shift+X）
'* Copyright:foxzz@163.com,2006/07/25 .
'* Author:   foxzz
'* Created:
'* Modified:
'* Version: 1.0
'* Comment: 遍历物理模型中的所有表，将字段的comment赋值到字段的code中。
'            在将code置换为comment过程中，需要考虑的问题
'            1、code必须唯一，而comment有可能不唯一。
'               处理办法是如果字段的comment重复，则字段的code=comment+1、2、3...
'            2、comment值有可能为空，这种情况下对字段的code不处理。
'               针对Oracle数据库,将comment on column 字段名称 is '';添加到C:\pdcomment.txt文件中。
'               在补充comment完毕后，便于在数据库中执行      
'******************************************************************************
 
 
Option Explicit
ValidationMode = True
InteractiveMode = im_Batch
 
 
Dim system, file
Set system = CreateObject("Scripting.FileSystemObject")
Dim ForReading, ForWriting, ForAppending   '打开文件选项
ForReading   = 1 ' 只读
ForWriting   = 2 ' 可写
ForAppending = 8 ' 可写并追加
'打开文本文件
Set file = system.OpenTextFile("D:\pdcomment.txt", ForWriting, true)
'判断当前model是否物理数据模型
Dim mdl
Set mdl = ActiveModel
If (mdl Is Nothing) Then
   MsgBox "处理对象无模型"
ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
   MsgBox "当前模型不是物理数据模型"
Else
   ProcessFolder mdl,file
End If
file.Close
 
 
 
 
'******************************************************************************
Private sub ProcessFolder(folder,file)
Dim i,j,k
i=0:j=0:k=0
'列数组，记录字段里不重复的comment
Dim ColumnComment()
Dim ColumnCommentNumber()
ReDim Preserve ColumnComment(i)
ReDim Preserve ColumnCommentNumber(i)
 
 
Dim tbl   '当前表
Dim col   '当前字段
dim curComment '当前字段comment
dim str
'处理模型中的表
for each tbl in folder.tables
    if not tbl.isShortcut then
       if len(trim(tbl.comment))<>0 then
          '可以在这里显示table的comment
          'tbl.code = tbl.code+"("+trim(tbl.comment)+")"
       end if 
 
		tbl.name = tbl.comment
		tbl.code = tbl.comment
 
       '处理表中的列
       for each col in tbl.columns
           k = 0
		   str=trim(col.comment)
		   'curComment=left(str,instrrev(str,";"))
		   curComment=str
           if len(curComment)<>0 then
              '遍历相异的comment数组
              for j = 0 to i
                  if ColumnComment(j) = curComment then
                     '如果找到相同的comment,则相关计数器加1
                     ColumnCommentNumber(j) = ColumnCommentNumber(j) + 1
                     k = j
                  end if
              Next
              '如果没有相同的comment,则k=0,此时ColumnCommentNumber(0)也为0
              '否则ColumnCommentNumber(k)不为0
              if ColumnCommentNumber(k) <> 0 then
                 col.name = curComment & cstr(ColumnCommentNumber(k))
				 col.code = curComment & cstr(ColumnCommentNumber(k))
              else
                 col.name = curComment
				 col.code = curComment
                 'ColumnComment(0)、ColumnCommentNumber(0)永远为空
                 '将相异的comment记录添加到数组中
                 i = i + 1
                 ReDim Preserve ColumnComment(i)
                 ReDim Preserve ColumnCommentNumber(i)
                 ColumnComment(i) = curComment
                 ColumnCommentNumber(i) = 0
              end if
           else
              '写入文件中
              file.WriteLine "comment on column "+ tbl.code+"."+col.name+" is '';"         
           end if
       next
    end if
    '由于不同表的code允许相同,因此此时重新初始化。
    '因为ColumnComment(0)、ColumnCommentNumber(0)为空，可以保留
    ReDim Preserve ColumnComment(0)
    ReDim Preserve ColumnCommentNumber(0)
    i=0:j=0:k=0
 
 
next
 
 
Dim view '当前视图
for each view in folder.Views
    if not view.isShortcut then
       '可以在这里显示view的comment
       'view.code = view.comment
    end if
next
'对子目录进行递归
Dim subpackage 'folder
For Each subpackage In folder.Packages
    if not subpackage.IsShortcut then
       ProcessFolder subpackage , file
    end if
Next
end sub
'******************************************************************************
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137