给基于cmake的工程添加uninstall功能

  我们知道，cmake提供了install指令可以让我们在项目构建完成后，通过make install命令，或者通过cmake --install . --prefix=<安装目录> 命令的方式来将CMakeLists.txt文件中通过install指令配置的文件安装到目标目录中。

  但是，cmake却没有提供uninstall指令来移除这些安装进去的文件的功能，这给工程的卸载添加了一些麻烦。为了实现卸载功能，我们只能自己来编写CMake脚本来实现。

  为了实现卸载功能，我们首先需要知道cmake在部署的时候在目标目录安装进去了哪些文件。幸好，cmake本身已经为我们准备了一个文件叫做install_manifest.txt，它包含了所有通过install指令安装的文件列表，每个文件占用一行。只要我们通过make install安装过，我们就可以在cmake的当前工作目录下面找到这个文件。

  因此，我们就可以利用这个install_manifest.txt文件来执行删除文件的操作，从而来达成卸载安装文件的目的。当然，我们可以用一个shell脚本只要少数几行代码来实现，但是，这里还是基于cmake，让用户能够已约定俗成的习惯方式通过make uninstall的方式来进行卸载操作。

  首先创建一个Uninstall.cmake.in 的文件，该文件和CMakeLists.txt放在一个目录下面，如下：

# CMAKE_BINARY_DIR变量指向cmake build tree的顶级目录。
if(NOT EXISTS "@CMAKE_BINARY_DIR@/install_manifest.txt")
  message(FATAL_ERROR "Cannot find install manifest: @CMAKE_BINARY_DIR@/install_manifest.txt")
endif()

# 从install_manifest.txt中读取文本内容，并根据\n拆分成一个文件列表
file(READ "@CMAKE_BINARY_DIR@/install_manifest.txt" files)
string(REGEX REPLACE "\n" ";" files "${files}")

# 循环删除列表中的文件
foreach(file ${files})
  message(STATUS "Uninstalling $ENV{DESTDIR}${file}")
  
  if(IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")
  
    # 调用cmake -E remove <文件名>来删除文件
    # 其中$ENV{DESTDIR}当make DESTDIR=<安装目录> install
    # 在命令行指定安装目录的将被设置，但是install_manifest.txt中
    # 的文件路径不包括DESTDIR指定的部分
    exec_program(
      "@CMAKE_COMMAND@" ARGS "-E remove \"$ENV{DESTDIR}${file}\""
      OUTPUT_VARIABLE rm_out
      RETURN_VALUE rm_retval
      )
      
    if(NOT "${rm_retval}" STREQUAL 0)
      message(FATAL_ERROR "Problem when removing $ENV{DESTDIR}${file}")
    endif()
    
  else(IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")
    message(STATUS "File $ENV{DESTDIR}${file} does not exist.")
  endif()
endforeach()

  然后在CMakeLists.txt文件中添加下面代码，如下：

# 创建卸载target
if(NOT TARGET uninstall)

  # 利用前面的Uninstall.cmake.in文件自动生成Uninstall.cmake
  configure_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/Uninstall.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/Uninstall.cmake"
    IMMEDIATE @ONLY)
  
  # 通过add_custom_target创建一个自定义构建目标的命令
  # 自定义目标可以在构建时被执行，但不会产生实际的构建输出。
  add_custom_target(uninstall
    COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/Uninstall.cmake)

endif()