• [AHK V2]SQLite测试用例

    AutoHotkey v2语言写的SQLite调用示例

    1. ; 创建一个SQLite对象
    2. db :=  CSQLite()
    3.  
    4. ; 打开数据库
    5. if !db.OpenDB("example.db") {
    6.     MsgBox "Failed to open database: " db.ErrorMsg
    7.     ExitApp
    8. }
    9.  
    10. ; 执行SQL查询
    11. sql := "CREATE TABLE IF NOT EXISTS users (id INTEGER PRIMARY KEY, name TEXT, age INTEGER);"
    12. if !db.Exec(sql) {
    13.     MsgBox "Failed to execute SQL: " db.ErrorMsg
    14.     db.CloseDB()
    15.     ExitApp
    16. }
    17.  
    18. ; 插入数据
    19. sql := "INSERT INTO users (name, age) VALUES ('John Doe', 30);"
    20. if !db.Exec(sql) {
    21.     MsgBox "Failed to insert data: " db.ErrorMsg
    22.     db.CloseDB()
    23.     ExitApp
    24. }
    25.  
    26. ; 查询数据
    27. sql := "SELECT * FROM users;"
    28. TB := {}
    29. if !db.GetTable(sql, &TB) {
    30.     MsgBox "Failed to query data: " db.ErrorMsg
    31.     db.CloseDB()
    32.     ExitApp
    33. }
    34.  
    35. ; 显示查询结果
    36. for row in TB.Rows {
    37.     MsgBox "ID: " row[1] ", Name: " row[2] ", Age: " row[3]
    38. }
    39.  
    40. ; 关闭数据库
    41. db.CloseDB()

    SQLite类源代码：

    1. /************************************************************************
    2.  * @description SQLite class
    3.  * @file CSQLite.ahk
    4.  * @author thqby
    5.  * @date 2022/04/23
    6.  * @version 0.0.4
    7.  * https://github.com/samfisherirl/Useful-AHK-v2-Libraries-and-Classes/blob/main/__thqby_Translation_SQLite_English/SQLite.ahk
    8.  ***********************************************************************/
    9. class CSQLite
    10. {
    11. 	static Version := "", _SQLiteDLL := A_ScriptDir . "\SQLite3.dll", _RefCount := 0, hModule:=0
    12. 	static _MinVersion := "3.29", execfunc_ptr := 0, callback_gettable_ptr := 0
    13.  
    14. 	__New(DllFolder:="") {
    15. 		this._Path := ""						; Database path											(String)
    16. 		this._Handle := 0					  ; Database handle										 (Pointer)
    17. 		if (CSQLite._RefCount = 0) {
    18. 			SQLiteDLL := CSQLite._SQLiteDLL
    19. 			if FileExist(DllFolder "\SQLite3.dll")
    20. 				SQLiteDLL := CSQLite._SQLiteDLL := DllFolder "\SQLite3.dll"
    21. 			if (!DllCall("GetModuleHandle", "Str", SQLiteDLL, "UPtr")
    22. 				&&!(CSQLite.hModule:=DllCall("LoadLibrary", "Str", SQLiteDLL, "UPtr"))){
    23. 				MsgBox("DLL " SQLiteDLL " does not exist!", "CSQLite Error", 16)
    24. 				ExitApp()
    25. 			}
    26. 			CSQLite.Version := StrGet(DllCall("SQLite3.dll\sqlite3_libversion", "Cdecl UPtr"), "UTF-8")
    27. 			SQLVersion := StrSplit(CSQLite.Version, ".")
    28. 			MinVersion := StrSplit(CSQLite._MinVersion, ".")
    29. 			if (SQLVersion[1] < MinVersion[1]) || ((SQLVersion[1] = MinVersion[1]) && (SQLVersion[2] < MinVersion[2])){
    30. 				DllCall("FreeLibrary", "Ptr", CSQLite.hModule), CSQLite.hModule:=0
    31. 				MsgBox("Version " . CSQLite.Version .  " of SQLite3.dll is not supported!`n`n"
    32. 					. "You can download the current version from www.sqlite.org!", "SQLite ERROR", 16)
    33. 				ExitApp()
    34. 			}
    35. 			CSQLite.execfunc_ptr := DllCall("GetProcAddress", "Ptr", DllCall("LoadLibrary", "Str", SQLiteDLL, "UPtr"), "AStr", "sqlite3_exec", "Ptr")
    36. 			CSQLite.callback_gettable_ptr := CallbackCreate(callback_gettable, "F C")
    37. 		}
    38. 		CSQLite._RefCount += 1
    39. 	}
    40. 	; ===================================================================================================================
    41. 	; DESTRUCTOR __Delete
    42. 	; ===================================================================================================================
    43. 	__Delete() {
    44. 		if (this._Thread.HasOwnProp("_Threadobj"))
    45. 			this._Thread._Threadobj:=""
    46. 		if (this._Handle)
    47. 			this.CloseDB()
    48. 		CSQLite._RefCount -= 1
    49. 		if (CSQLite._RefCount = 0) {
    50. 			CallbackFree(CSQLite.callback_gettable_ptr)
    51. 			if (CSQLite.hModule)
    52. 				DllCall("FreeLibrary", "Ptr", CSQLite.hModule)
    53. 		}
    54. 	}
    55. 	; ===================================================================================================================
    56. 	; PRIVATE _StrToUTF8
    57. 	; ===================================================================================================================
    58. 	_StrToUTF8(Str, &UTF8) => (VarSetStrCapacity(&UTF8, size:=StrPut(Str, "UTF-8")), StrPut(Str, StrPtr(UTF8), "UTF-8"), size)
    59.  
    60. 	; ===================================================================================================================
    61. 	; PRIVATE _ErrMsg
    62. 	; ===================================================================================================================
    63. 	_UTF8ToStr(UTF8) => StrGet(StrPtr(UTF8), "UTF-8")
    64. 	
    65.    ; ===================================================================================================================
    66.    ; PRIVATE _ErrMsg
    67.    ; ===================================================================================================================
    68. 	_ErrMsg() => ((RC := DllCall("SQLite3.dll\sqlite3_errmsg", "Ptr", this._Handle, "Cdecl UPtr")) ? StrGet(StrPtr(RC), "UTF-8") : "")
    69. 	
    70.    ; ===================================================================================================================
    71.    ; PRIVATE _ErrCode
    72.    ; ===================================================================================================================
    73. 	_ErrCode() => DllCall("SQLite3.dll\sqlite3_errcode", "Ptr", this._Handle, "Cdecl Int")
    74. 	
    75.    ; ===================================================================================================================
    76.    ; PRIVATE _Changes
    77.    ; ===================================================================================================================
    78. 	_Changes() => DllCall("SQLite3.dll\sqlite3_changes", "Ptr", this._Handle, "Cdecl Int")
    79. 	
    80.    ; ===================================================================================================================
    81.    ; PRIVATE _Returncode
    82.    ; ===================================================================================================================
    83. _ReturnMsg(RC) {
    84.     static Msg := Map(1,    "SQL error or missing database"
    85. 	                , 2,    "SQLite internal logic error"
    86. 	                , 3,    "Access denied"
    87. 	                , 4,    "Callback function requested operation cancellation"
    88. 	                , 5,    "Database file is locked"
    89. 	                , 6,    "A table in the database is locked"
    90. 	                , 7,    "A malloc() function call failed"
    91. 	                , 8,    "Attempt to write to a read-only database"
    92. 	                , 9,    "Operation interrupted by sqlite3_interrupt() function"
    93. 	                , 10,   "Some disk I/O error occurred"
    94. 	                , 11,   "Incorrect database disk image"
    95. 	                , 12,   "Unknown opcode in sqlite3_file_control()"
    96. 	                , 13,   "Insertion failed due to database full"
    97. 	                , 14,   "Unable to open the database file"
    98. 	                , 15,   "Database lock protocol error"
    99. 	                , 16,   "Database is empty"
    100. 	                , 17,   "Data structure has changed"
    101. 	                , 18,   "String or binary data exceeds size limit"
    102. 	                , 19,   "Cancelled due to constraint violation"
    103. 	                , 20,   "Data type mismatch"
    104. 	                , 21,   "Incorrect library usage"
    105. 	                , 22,   "Use of unsupported operating system feature"
    106. 	                , 23,   "Authorization failed"
    107. 	                , 24,   "Attached database format error"
    108. 	                , 25,   "Second parameter passed to sqlite3_bind() is out of range"
    109. 	                , 26,   "The opened file is not a database file"
    110. 	                , 100,  "sqlite3_step() has produced a row result"
    111. 	                , 101,  "sqlite3_step() completed the execution operation")
    112.     return Msg.HasKey(RC) ? Msg[RC] : ""
    113. }
    114.    ; ===================================================================================================================
    115.    ; Properties
    116.    ; ===================================================================================================================
    117. 	ErrorMsg := ""              ; Error message                           (String) 
    118. 	ErrorCode := 0              ; SQLite error code / ErrorLevel          (Variant)
    119. 	Changes := 0                ; Changes made by last call of Exec()     (Integer)
    120. 	SQL := ""                   ; Last executed SQL statement             (String)
    121. 	_Thread := {_Threadobj:0, queue:[], pexec:0, DB:0}
    122. 	OpenDB(DBPath, Access := "W", Create := true) {
    123. 		static SQLITE_OPEN_READONLY  := 0x01 ; Database opened as read-only
    124. 		static SQLITE_OPEN_READWRITE := 0x02 ; Database opened as read-write
    125. 		static SQLITE_OPEN_CREATE    := 0x04 ; Database will be created if not exists
    126. 		static MEMDB := ":memory:"
    127. 		this.ErrorMsg := "", this.ErrorCode := 0
    128. 		if (DBPath = "")
    129. 			DBPath := MEMDB
    130. 		if (DBPath = this._Path) && (this._Handle)
    131. 			return true
    132. 		if (this._Handle)
    133. 			return (this.ErrorMsg := "You must first close DB " . this._Path . "!", false)
    134. 		Flags := 0, Access := SubStr(Access, 1, 1)
    135. 		if (Access != "W") && (Access != "R")
    136. 			Access := "R"
    137. 		Flags := SQLITE_OPEN_READONLY
    138. 		if (Access = "W") {
    139. 			Flags := SQLITE_OPEN_READWRITE
    140. 			if (Create)
    141. 				Flags |= SQLITE_OPEN_CREATE
    142. 		}
    143. 		this._Path := DBPath, this._StrToUTF8(DBPath, &UTF8:="")
    144. 		if (RC := DllCall("SQLite3.dll\sqlite3_open_v2", "Ptr", StrPtr(UTF8), "Ptr*", &HDB:=0, "Int", Flags, "Ptr", 0, "Cdecl Int"))
    145. 			return (this._Path := "", this.ErrorMsg := this._ErrMsg(), this.ErrorCode := RC, false)
    146. 		this._Handle := HDB
    147. 		this.createScalarFunction(regexp, 2)
    148. 		this.createScalarFunction(regex_replace, 3)
    149. 		return true
    150. 	}
    151.    ; ===================================================================================================================
    152.    ; METHOD CloseDB        Close database
    153.    ; Parameters:           None
    154.    ; return values:        On success  - true
    155.    ;                       On failure  - false, ErrorMsg / ErrorCode contain additional information
    156.    ; ===================================================================================================================
    157. 	CloseDB() {
    158. 		this.ErrorMsg := "", this.ErrorCode := 0, this.SQL := ""
    159. 		if !(this._Handle)
    160. 			return true
    161. 		if (RC := DllCall("SQLite3.dll\sqlite3_close", "Ptr", this._Handle, "Cdecl Int"))
    162. 			return (this.ErrorMsg := this._ErrMsg(), this.ErrorCode := RC, false)
    163. 		this._Path := "", this._Handle := ""
    164. 		return true
    165. 	}
    166.    ; ===================================================================================================================
    167. 	LoadOrSaveDb(DBPath, isSave:=0){
    168. 		static SQLITE_OPEN_READONLY  := 0x01 ; Database opened as read-only
    169. 		static SQLITE_OPEN_READWRITE := 0x02 ; Database opened as read-write
    170. 		static SQLITE_OPEN_CREATE    := 0x04 ; Database will be created if not exists
    171. 		this.ErrorMsg := "", this.ErrorCode := 0, HDB := 0
    172. 		if (DBPath = "")
    173. 			return false
    174. 		if (!this._Handle)
    175. 			return (this.ErrorMsg := "You must first Open Memory DB!", false)
    176. 		Flags := SQLITE_OPEN_READWRITE, Flags |= SQLITE_OPEN_CREATE
    177. 		this._StrToUTF8(isSave?(tmp:=StrReplace(DBPath, ".db", ".tmp")):DBPath, &UTF8:="")
    178. 		if (RC := DllCall("SQLite3.dll\sqlite3_open_v2", "Ptr", StrPtr(UTF8), "Ptr*", &HDB, "Int", Flags, "Ptr", 0, "Cdecl Int"))
    179. 			return (this.ErrorMsg := this._ErrMsg(), this.ErrorCode := RC, false)
    180. 		pFrom := (isSave ? this._Handle : HDB), pTo   := (isSave ? HDB : this._Handle), this._StrToUTF8("main", &UTF8)
    181. 		pBackup := DllCall("SQLite3.dll\sqlite3_backup_init", "Ptr", pTo, "Ptr", StrPtr(UTF8), "Ptr", pFrom, "Ptr", StrPtr(UTF8), "Cdecl Int")
    182. 		if (pBackup){
    183. 			DllCall("SQLite3.dll\sqlite3_backup_step", "Ptr", pBackup, "Int", -1, "Cdecl Int")
    184. 			DllCall("SQLite3.dll\sqlite3_backup_finish", "Ptr", pBackup, "Cdecl Int")
    185. 		}
    186. 		RC := DllCall("SQLite3.dll\sqlite3_errcode", "Ptr", pTo, "Cdecl Int")
    187. 		DllCall("SQLite3.dll\sqlite3_close", "Ptr", HDB, "Cdecl Int")
    188. 		if (RC) {
    189. 			this._Path := "", this.ErrorMsg := this._ErrMsg(), this.ErrorCode := RC
    190. 			if (isSave)
    191. 				FileDelete tmp
    192. 			return false
    193. 		}
    194. 		if (isSave){
    195. 			if (FileGetSize(tmp, "K")<16)
    196. 				return (FileDelete(tmp), false)
    197. 			FileMove tmp, DBPath, 1
    198. 			this.Changes:=0
    199. 		}
    200. 		return true
    201. 	}
    202.    ; ===================================================================================================================
    203.    ; METHOD AttachDB       Add another database file to the current database connection
    204.    ;                       http://www.sqlite.org/lang_attach.html
    205.    ; Parameters:           DBPath      - Path of the database file
    206.    ;                       DBAlias     - Database alias name used internally by SQLite
    207.    ; return values:        On success  - true
    208.    ;                       On failure  - false, ErrorMsg / ErrorCode contain additional information
    209.    ; ===================================================================================================================
    210. 	AttachDB(DBPath, DBAlias) => this.Exec("ATTACH DATABASE '" . DBPath . "' As " . DBAlias . ";")
    211.  
    212.    ; ===================================================================================================================
    213.    ; METHOD DetachDB       Detaches an additional database connection previously attached using AttachDB()
    214.    ;                       http://www.sqlite.org/lang_detach.html
    215.    ; Parameters:           DBAlias     - Database alias name used with AttachDB()
    216.    ; return values:        On success  - true
    217.    ;                       On failure  - false, ErrorMsg / ErrorCode contain additional information
    218.    ; ===================================================================================================================
    219. 	DetachDB(DBAlias) => this.Exec("DETACH DATABASE " . DBAlias . ";")
    220.  
    221. 	class Thread
    222. 	{
    223. 		Ptr:=0, pfunc:=0
    224. 		__New(funcobj, params, initflag:=0){
    225. 			this.pfunc:=pfunc:=CallbackCreate(funcobj)
    226. 			if (!this.Ptr:=DllCall("msvcrt\_beginthreadex", "Ptr", 0, "UInt", 0, "Ptr", pfunc, "Ptr", ObjPtrAddRef(params), "UInt", initflag, "UInt*", &threadid:=0))
    227. 				throw Error("create thread fail")
    228. 			this.threadid:=threadid
    229. 		}
    230.  
    231. 		__Delete()=>(CallbackFree(this.pfunc), (this.ExitCode=259)?this.Terminate():"", (this.Ptr?DllCall("Kernel32\CloseHandle", "Ptr", this):0))
    232. 		Terminate(dwExitCode:=1)=>(DllCall("Kernel32\TerminateThread", "Ptr", this, "UInt", dwExitCode))
    233. 		ExitCode=>(DllCall("Kernel32\GetExitCodeThread", "Ptr", this, "UInt*", &Code:=0)?Code:0)
    234. 	}
    235. 	ExecByThread(SQL){
    236. 		if !(this._Handle)
    237. 			return (this.ErrorMsg := "Invalid database handle!", false)
    238. 		s:=StrPut(SQL, "UTF-8"), this._Thread.queue.Push(Buffer(s)), StrPut(SQL, this._Thread.queue[-1], "UTF-8")
    239. 		if (this._Thread.pexec)
    240. 			return
    241. 		this._Thread.DB:=this, this._Thread.pexec:=CSQLite.execfunc_ptr
    242. 		this._Thread._Threadobj:=CSQLite.Thread(_Exec, this._Thread)
    243. 		
    244. 		_Exec(pinfo){
    245. 			_Thread:=ObjFromPtr(pinfo), hdb:=_Thread.DB._Handle, pexec:=_Thread.pexec
    246. 			while (_Thread.queue.Has(1)){
    247. 				if (RC:=DllCall(pexec, "Ptr", hdb, "Ptr", _Thread.queue[1], "Ptr", 0, "Ptr", 0, "Ptr*", &Err:=0, "Cdecl Int")){
    248. 					ErrMsg:=_Thread.DB._ReturnMsg(RC), DllCall("SQLite3.dll\sqlite3_free", "Ptr", Err, "Cdecl")
    249. 					throw Error(ErrMsg)
    250. 				}
    251. 				_Thread.queue.RemoveAt(1)
    252. 			}
    253. 			_Thread.DB:="", _Thread.pexec:=0
    254. 			return 0
    255. 		}
    256. 	}
    257. 	Exec(SQL, pCallback := 0) {
    258. 		this.ErrorMsg := "", this.ErrorCode := 0, this.SQL := SQL
    259. 		if !(this._Handle)
    260. 			return (this.ErrorMsg := "Invalid database handle!", false)
    261. 		this._StrToUTF8(SQL, &UTF8:="")
    262. 		RC := DllCall(CSQLite.execfunc_ptr, "Ptr", this._Handle, "Ptr", StrPtr(UTF8), "Ptr", pCallback, "Ptr", ObjPtrAddRef(this), "Ptr*", &Err:=0, "Cdecl Int")
    263. 		if (RC) {
    264. 			this.ErrorMsg := this._ReturnMsg(RC)
    265. 			if (this.ErrorMsg = "")
    266. 				this.ErrorMsg := StrGet(Err, "UTF-8")
    267. 			this.ErrorCode := RC
    268. 			DllCall("SQLite3.dll\sqlite3_free", "Ptr", Err, "Cdecl")
    269. 			return false
    270. 		}
    271. 		this.Changes := this._Changes()
    272. 		return true
    273. 	}
    274. 	GetTable(SQL, &TB, pcall := 0) {
    275. 		this.ErrorMsg := "", this.ErrorCode := 0, this.SQL := SQL
    276. 		if !(this._Handle)
    277. 			return (this.ErrorMsg := "Invalid database handle!", false)
    278. 		this._StrToUTF8(SQL, &UTF8:=""), TB := {RowCount:0, Rows:[]}
    279. 		RC := DllCall(CSQLite.execfunc_ptr, "Ptr", this._Handle, "Ptr", StrPtr(UTF8)
    280. 			, "Ptr", (pcall>0?pcall:CSQLite.callback_gettable_ptr), "Ptr", ObjPtrAddRef(TB), "Ptr*", &Err:=0, "Cdecl Int")
    281. 		if (RC) {
    282. 			this.ErrorMsg := this._ReturnMsg(RC)
    283. 			if (this.ErrorMsg = "")
    284. 				this.ErrorMsg := StrGet(Err, "UTF-8"), this.Err := ""
    285. 			else
    286. 				this.Err := StrGet(Err, "UTF-8")
    287. 			this.ErrorCode := RC, DllCall("SQLite3.dll\sqlite3_free", "Ptr", Err, "Cdecl")
    288. 			return false
    289. 		} else if (pcall<0){
    290. 			RC := DllCall("SQlite3.dll\sqlite3_prepare_v2", "Ptr", This._Handle, "Ptr", StrPtr(UTF8), "Int", -1, "Ptr*", &Stmt:=0, "Ptr", 0, "Cdecl Int")
    291. 			TB.Cols := [], TB.ColCount := DllCall("SQlite3.dll\sqlite3_column_count", "Ptr", Stmt, "Cdecl Int")
    292. 			Loop TB.ColCount
    293. 				TB.Cols.Push(StrGet(DllCall("SQlite3.dll\sqlite3_column_name16", "Ptr", Stmt, "Int", A_Index - 1, "Cdecl UPtr"), "UTF-16"))
    294. 			DllCall("SQLite3.dll\sqlite3_finalize", "Ptr", Stmt, "Cdecl Int")
    295. 		}
    296. 		return true
    297. 	}
    298. 	createScalarFunction(func, params) {
    299. 		argType := Type(func)
    300. 		if (argType != "Func" && argType != "Closure")
    301. 			throw Error(this.__class "::" A_thisFunc " - First parameter not a Func object", -1)
    302. 		else if (!func.name)
    303. 			throw Error(this.__class "::" A_thisFunc " - Function must be named", -1)
    304. 		this.ErrorMsg := "", this.ErrorCode := 0, cb := CallbackCreate(func, "F C")
    305. 		if (err := DllCall("SQLite3.dll\sqlite3_create_function16", "Ptr", this._handle, "Str", func.name, "Int", params, "Int", 0x801, "Ptr", 0, "Ptr", cb, "Ptr", 0, "Ptr", 0, "Cdecl Int"))
    306. 			return (this.ErrorMsg := this._ErrMsg(), this.ErrorCode := err, false)
    307. 		return true
    308. 	}
    309. 	LastInsertRowID(&RowID) {
    310. 		this.ErrorMsg := "", this.ErrorCode := 0, this.SQL := ""
    311. 		if !(this._Handle)
    312. 			return (this.ErrorMsg := "Invalid database handle!", false)
    313. 		RowID := DllCall("SQLite3.dll\sqlite3_last_insert_rowid", "Ptr", this._Handle, "Cdecl Int64")
    314. 		return true
    315. 	}
    316. 	TotalChanges(&Rows) {
    317. 		this.ErrorMsg := "", this.ErrorCode := 0, this.SQL := ""
    318. 		if !(this._Handle)
    319. 			return (this.ErrorMsg := "Invalid database handle!", false)
    320. 		Rows := DllCall("SQLite3.dll\sqlite3_total_changes", "Ptr", this._Handle, "Cdecl Int")
    321. 		return true
    322. 	}
    323. 	SetTimeout(Timeout := 1000) {
    324. 		this.ErrorMsg := "", this.ErrorCode := 0, this.SQL := ""
    325. 		if !(this._Handle)
    326. 			return (this.ErrorMsg := "Invalid database handle!", false)
    327. 		if !IsInteger(Timeout)
    328. 			Timeout := 1000
    329. 		RC := DllCall("SQLite3.dll\sqlite3_busy_timeout", "Ptr", this._Handle, "Int", Timeout, "Cdecl Int")
    330. 		if (RC)
    331. 			return (this.ErrorMsg := this._ErrMsg(), this.ErrorCode := RC, false)
    332. 		return true
    333. 	}
    334. }
    335.  
    336. regexp(Context, ArgC, vals) {
    337. 	regexNeedle := DllCall("SQLite3.dll\sqlite3_value_text16", "Ptr", NumGet(vals + 0, "Ptr"), "Cdecl Str")
    338. 	search := DllCall("SQLite3.dll\sqlite3_value_text16", "Ptr", NumGet(vals + A_PtrSize, "Ptr"), "Cdecl Str")
    339. 	DllCall("SQLite3.dll\sqlite3_result_int", "Ptr", Context, "Int", RegexMatch(search, regexNeedle), "Cdecl") ; 0 = false, 1 = true
    340. }
    341. regex_replace(Context, ArgC, vals) {
    342. 	search := DllCall("SQLite3.dll\sqlite3_value_text16", "Ptr", NumGet(vals + 0, "Ptr"), "Cdecl Str")
    343. 	regexNeedle := DllCall("SQLite3.dll\sqlite3_value_text16", "Ptr", NumGet(vals + A_PtrSize, "Ptr"), "Cdecl Str")
    344. 	Replacement := DllCall("SQLite3.dll\sqlite3_value_text16", "Ptr", NumGet(vals + A_PtrSize*2, "Ptr"), "Cdecl Str")
    345. 	DllCall("SQLite3.dll\sqlite3_result_text16", "Ptr", Context, "Str", RegExReplace(search, regexNeedle, Replacement), "Int", -1, "Ptr", 0, "Cdecl")
    346. }
    347. callback_gettable(TB, coln, vals, cols) {
    348. 	arr := Array(), TBobj := ObjFromPtrAddRef(TB)
    349. 	Loop coln
    350. 		arr.Push(StrGet(NumGet(vals + A_PtrSize * (A_Index - 1), "Ptr"), "UTF-8"))
    351. 	TBobj.Rows.Push(arr), TBobj.RowCount++
    352. 	return 0
    353. }

  • 相关阅读:
    VUE 2.0——vue入门和v-bind使用
    js中setTimeout定时器不准的原因，以及修正的办法
    Android Studio运行kotlin项目，一直Read timed out
    图论的小技巧以及扩展
    BERT模型的详细介绍
    当今微服务盛行之架构师必经之路-领域驱动设计-上
    八、SpringMVC（2）
    安装Elasticsearch步骤（包含遇到的问题及解决方案）
    系统软件开发平台的介绍
    Java面试题：讨论单例模式的实现方式，包括懒汉式和饿汉式，并讨论线程安全问题
  • 原文地址：https://blog.csdn.net/liuyukuan/article/details/140274815