• 《Unity Shader入门精要》笔记05

    Unity中的基础光照

    在UnityShader中实现漫反射光照模型

    漫反射计算公式 = （入射光线强度和颜色 * 材质的漫反射系数）* max(0,表面法线 · 光源方向)

    逐顶点光照

    Shader "Custom/DiffuseShader"
{
    Properties
    {
        _Diffuse ("Diffuse",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            Tags{"LightMode" = "ForwardBase"} //只有定义了正确的光照模式，才能得到一些Unity的内置光照变量 例如LightColor0
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc" //为了使用LightColor0


            fixed4 _Diffuse; //为了使用properties的属性 需要定义

            struct a2v
            {
                float4 vertext : POSITION;
                float3 normal : NORMAL; //储存法线信息
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR; //为了存储定点中的颜色信息
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertext);
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //法线要和光源方向进行点积之前 要保证在同一坐标系下 a2v得到的normal是在模型空间下的 需要转换到世界空间中
                fixed3 worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                
                //_WorldSpaceLightPos0光源方向 如果有同时多个光源 这个就不是正确结果
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                //_LightColor0该Pass处理的光源的颜色和强度信息
                //saturate是cg提供的函数 可以把参数截取在0-1范围内 防止为负数
                // 光源颜色和强度 * 材质漫反射颜色 * 顶点法线和光源方向点积
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));

                o.color = ambient + diffuse;
                return o;
            }
            fixed4 frag(v2f i) : SV_Target
            {
                return fixed4(i.color, 1.0);//输出顶点颜色
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}


    • 1
    • 2
    • 3
    • 4
    • 5
    • 6
    • 7
    • 8
    • 9
    • 10
    • 11
    • 12
    • 13
    • 14
    • 15
    • 16
    • 17
    • 18
    • 19
    • 20
    • 21
    • 22
    • 23
    • 24
    • 25
    • 26
    • 27
    • 28
    • 29
    • 30
    • 31
    • 32
    • 33
    • 34
    • 35
    • 36
    • 37
    • 38
    • 39
    • 40
    • 41
    • 42
    • 43
    • 44
    • 45
    • 46
    • 47
    • 48
    • 49
    • 50
    • 51
    • 52
    • 53
    • 54
    • 55
    • 56
    • 57
    • 58
    • 59
    • 60
    • 61

    逐像素光照

    Shader "Custom/DiffuseShader"
{
    Properties
    {
        _Diffuse ("Diffuse",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            Tags{"LightMode" = "ForwardBase"} //只有定义了正确的光照模式，才能得到一些Unity的内置光照变量 例如LightColor0
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc" //为了使用LightColor0


            fixed4 _Diffuse; //为了使用properties的属性 需要定义

            struct a2v
            {
                float4 vertext : POSITION;
                float3 normal : NORMAL; //储存法线信息
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 worldNormal : TEXCOORD0; //为了存储定点中的颜色信息
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertext);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                return o;
            }
            fixed4 frag(v2f i) : SV_Target
            {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                fixed3 worldNormal = normalize(i.worldNormal);
                
                //_WorldSpaceLightPos0光源方向 如果有同时多个光源 这个就不是正确结果
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                //_LightColor0该Pass处理的光源的颜色和强度信息
                //saturate是cg提供的函数 可以把参数截取在0-1范围内 防止为负数
                // 光源颜色和强度 * 材质漫反射颜色 * 顶点法线和光源方向点积
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                fixed3 color = ambient + diffuse;
                return fixed4(color, 1.0);//输出顶点颜色
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}


    • 1
    • 2
    • 3
    • 4
    • 5
    • 6
    • 7
    • 8
    • 9
    • 10
    • 11
    • 12
    • 13
    • 14
    • 15
    • 16
    • 17
    • 18
    • 19
    • 20
    • 21
    • 22
    • 23
    • 24
    • 25
    • 26
    • 27
    • 28
    • 29
    • 30
    • 31
    • 32
    • 33
    • 34
    • 35
    • 36
    • 37
    • 38
    • 39
    • 40
    • 41
    • 42
    • 43
    • 44
    • 45
    • 46
    • 47
    • 48
    • 49
    • 50
    • 51
    • 52
    • 53
    • 54
    • 55
    • 56
    • 57
    • 58
    • 59
    • 60

    半兰伯特模型

    Half Lambert 半兰伯特光照模型改善逐像素光照中的背光区域失去模型细节表现的问题，仅为视觉增强
    广义的半兰伯特光照模型公式 = （入射光线强度和颜色 * 材质的漫反射系数）* （α(表面法线 · 光源方向) + β）
    大多数情况下 α 和 β 的值均为0.5

    Shader "Custom/HalfLambert"
{
    Properties
    {
        _Diffuse ("Diffuse",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            Tags{"LightMode" = "ForwardBase"} //只有定义了正确的光照模式，才能得到一些Unity的内置光照变量 例如LightColor0
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc" //为了使用LightColor0


            fixed4 _Diffuse; //为了使用properties的属性 需要定义

            struct a2v
            {
                float4 vertext : POSITION;
                float3 normal : NORMAL; //储存法线信息
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 worldNormal : TEXCOORD0; //为了存储定点中的颜色信息
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertext);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                return o;
            }
            fixed4 frag(v2f i) : SV_Target
            {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                fixed3 worldNormal = normalize(i.worldNormal);
                
                //_WorldSpaceLightPos0光源方向 如果有同时多个光源 这个就不是正确结果
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                fixed halfLambert = dot(worldNormal,worldLightDir) * 0.5 + 0.5;
                //_LightColor0该Pass处理的光源的颜色和强度信息
                // 光源颜色和强度 * 材质漫反射颜色 * halfLambert
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * halfLambert;
                fixed3 color = ambient + diffuse;
                return fixed4(color, 1.0);//输出顶点颜色
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}


    • 1
    • 2
    • 3
    • 4
    • 5
    • 6
    • 7
    • 8
    • 9
    • 10
    • 11
    • 12
    • 13
    • 14
    • 15
    • 16
    • 17
    • 18
    • 19
    • 20
    • 21
    • 22
    • 23
    • 24
    • 25
    • 26
    • 27
    • 28
    • 29
    • 30
    • 31
    • 32
    • 33
    • 34
    • 35
    • 36
    • 37
    • 38
    • 39
    • 40
    • 41
    • 42
    • 43
    • 44
    • 45
    • 46
    • 47
    • 48
    • 49
    • 50
    • 51
    • 52
    • 53
    • 54
    • 55
    • 56
    • 57
    • 58
    • 59
    • 60

    在Unity Shader中实现高光反射光照模型

    基本光照模型中高光反射部分 = （入射光线的颜色和强度 * 材质的高光反射系数）max（0,视角方向·反射方向）^ 高光区域大小
    反射方向 = 光源方向 - 2（表面法线 · 光源方向）表面法线
    CG提供了计算反射方向的函数refect(入射方向,法线方向)

    逐顶点光照

    Shader "Custom/SpecularShader"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8.0,256)) = 20
    }
    SubShader
    {
        //顶点 片元着色器的代码要写在Pass语义块 而非SubShader语义块
        Pass
        {
            Tags { "LightMode"="ForwardBase" }
            
            CGPROGRAM

            #pragma vertex vert;
            #pragma fragment frag;

            #include "Lighting.cginc"

            fixed4 _Diffuse; //颜色范围在0-1之间 可以用fixed来储存
            fixed4 _Specular;
            float _Gloss;//范围很大

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                //计算漫反射部分与上一节一致
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                fixed3 worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

                //由于Cg的reflect函数的入射方向要求是由光源指向焦点处的 所以我们需要对worlLightDir取反
                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                //摄像机位置 - 世界空间下的顶点位置 得到一个方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld,v.vertex).xyz);
                //代入公式 pow计算次幂
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);

                o.color = ambient + diffuse + specular;
                return o;
            }
            fixed4 frag(v2f i) : SV_Target
            {
                return fixed4(i.color,1.0);
            }
            
            ENDCG
        }
    }
    FallBack "Specular"
}


    • 1
    • 2
    • 3
    • 4
    • 5
    • 6
    • 7
    • 8
    • 9
    • 10
    • 11
    • 12
    • 13
    • 14
    • 15
    • 16
    • 17
    • 18
    • 19
    • 20
    • 21
    • 22
    • 23
    • 24
    • 25
    • 26
    • 27
    • 28
    • 29
    • 30
    • 31
    • 32
    • 33
    • 34
    • 35
    • 36
    • 37
    • 38
    • 39
    • 40
    • 41
    • 42
    • 43
    • 44
    • 45
    • 46
    • 47
    • 48
    • 49
    • 50
    • 51
    • 52
    • 53
    • 54
    • 55
    • 56
    • 57
    • 58
    • 59
    • 60
    • 61
    • 62
    • 63
    • 64
    • 65
    • 66
    • 67
    • 68
    • 69

    高光部分明显不平滑，因为高光反射部分计算是非线性的，在顶点着色器中计算光照再进行插值的过程是线性的，破坏了原计算非线性关系，会出现视觉问题。

    逐像素光照

    Shader "Custom/SpecularFragShader"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8.0,256)) = 20
    }
    SubShader
    {
        //顶点 片元着色器的代码要写在Pass语义块 而非SubShader语义块
        Pass
        {
            Tags { "LightMode"="ForwardBase" }
            
            CGPROGRAM

            #pragma vertex vert;
            #pragma fragment frag;

            #include "Lighting.cginc"

            fixed4 _Diffuse; //颜色范围在0-1之间 可以用fixed来储存
            fixed4 _Specular;
            float _Gloss;//范围很大

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
            };

            //计算世界空间下的法线方向和顶点坐标，传递给片元着色器
            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                return o;
            }
            fixed4 frag(v2f i) : SV_Target
            {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);

                return fixed4(ambient + diffuse + specular,1.0);
            }
            
            ENDCG
        }
    }
    FallBack "Specular"
}


    • 1
    • 2
    • 3
    • 4
    • 5
    • 6
    • 7
    • 8
    • 9
    • 10
    • 11
    • 12
    • 13
    • 14
    • 15
    • 16
    • 17
    • 18
    • 19
    • 20
    • 21
    • 22
    • 23
    • 24
    • 25
    • 26
    • 27
    • 28
    • 29
    • 30
    • 31
    • 32
    • 33
    • 34
    • 35
    • 36
    • 37
    • 38
    • 39
    • 40
    • 41
    • 42
    • 43
    • 44
    • 45
    • 46
    • 47
    • 48
    • 49
    • 50
    • 51
    • 52
    • 53
    • 54
    • 55
    • 56
    • 57
    • 58
    • 59
    • 60
    • 61
    • 62
    • 63
    • 64
    • 65
    • 66
    • 67
    • 68

    Blinn-Phong光照模型

    Blinn模型没有使用反射方向，而是引入了一个新的矢量，新矢量是通过对视角方向和光照方向相加后再归一化得到的。
    Blinn模型计算高光反射公式 = (入射光线颜色和强度 · 材质的高光反射系数)max(0,表面法线·新矢量)^高光区域大小

    Shader "Custom/BlinnPhong"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8.0,256)) = 20
    }
    SubShader
    {
        //顶点 片元着色器的代码要写在Pass语义块 而非SubShader语义块
        Pass
        {
            Tags { "LightMode"="ForwardBase" }
            
            CGPROGRAM

            #pragma vertex vert;
            #pragma fragment frag;

            #include "Lighting.cginc"

            fixed4 _Diffuse; //颜色范围在0-1之间 可以用fixed来储存
            fixed4 _Specular;
            float _Gloss;//范围很大

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
            };

            //计算世界空间下的法线方向和顶点坐标，传递给片元着色器
            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                return o;
            }
            fixed4 frag(v2f i) : SV_Target
            {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,halfDir)),_Gloss);

                return fixed4(ambient + diffuse + specular,1.0);
            }
            
            ENDCG
        }
    }
    FallBack "Specular"
}


    • 1
    • 2
    • 3
    • 4
    • 5
    • 6
    • 7
    • 8
    • 9
    • 10
    • 11
    • 12
    • 13
    • 14
    • 15
    • 16
    • 17
    • 18
    • 19
    • 20
    • 21
    • 22
    • 23
    • 24
    • 25
    • 26
    • 27
    • 28
    • 29
    • 30
    • 31
    • 32
    • 33
    • 34
    • 35
    • 36
    • 37
    • 38
    • 39
    • 40
    • 41
    • 42
    • 43
    • 44
    • 45
    • 46
    • 47
    • 48
    • 49
    • 50
    • 51
    • 52
    • 53
    • 54
    • 55
    • 56
    • 57
    • 58
    • 59
    • 60
    • 61
    • 62
    • 63
    • 64
    • 65
    • 66
    • 67
    • 68

    Blinn-Phong光照模型的高光反射部分看起来更大、更亮一些。在实际渲染中，绝大多数情况会选择这个光照模型，仅是因为更符合实验效果。

    召唤神龙：使用Unity内置的函数

    UnityCG.cginc

    函数名描述
    float3 WorldSpaceViewDir( in float4 localPos )输入一个模型空间中的顶点位置，返回世界空间中从该点到摄像机的观察方向。内部实现使用了UnityWorldSpaceViewDir函数
    float3 UnityWorldSpaceViewDir( in float3 worldPos )输入一个世界空间中的顶点位置，返回世界空间中从该点到摄像机的观察方向
    float3 ObjSpaceViewDir( in float4 v )输入一个模型空间中的顶点位置，返回模型空间中从该点到摄像机的观察方向
    float3 WorldSpaceLightDir( in float4 localPos )仅可用于前向渲染中。输入一个模型空间中的顶点位置，返回世界空间中从该点到光源的光照方向。内部实现使用了UnityWorldSpaceLightDir函数。没有被归一化
    float3 UnityWorldSpaceLightDir( in float3 worldPos )仅可用于前向渲染中。输入一个世界空间中的顶点位置，返回世界空间中从该点到光源的光照方向。没有被归一化
    float3 ObjSpaceLightDir( in float4 v )仅可用于前向渲染中。输入一个模型空间中的顶点位置，返回模型空间中，从该点到光源的光照方向。没有被归一化
    float3 UnityObjectToWorldNormal( in float3 norm )把法线方向从模型空间转换到世界空间中
    float3 UnityObjectToWorldDir( in float3 dir )把方向矢量从模型空间变换到世界空间中
    float3 UnityWorldToObjectDir( in float3 dir )把方向矢量从世界空间变换到模型空间中

    计算光源的三个函数WorldSpaceLightDir、UnityWorldSpaceLightDir、ObjSpaceLightDir稍微复杂，只有在向前渲染时，函数里的内置变量_WorldSpaceLightPos0等才会被正确赋值

    内置函数得到的方向是没有被归一化的，需要使用normalize函数来对结果进行归一化。

  • 相关阅读:
    IS420ESWBH3A GE 附加配置文件和I/O组件中的单独标签
    这些负载均衡都解决哪些问题？服务、网关、NGINX？
    语义分割，实例分割，全景分割梳理
    【Newman+Jenkins】实施接口自动化测试
    Qt_基础
    基于docker进行Grafana + prometheus实现服务监听
    基于Java毕业设计影片推荐系统源码+系统+mysql+lw文档+部署软件
    解决idea运行maven项目报错Unresolved plugin ‘org.apache.maven.pluginsxxxx
    如何做好接口自动化测试？
    手机怎么把图片转换成Word？这个小妙招大家要学会
  • 原文地址：https://blog.csdn.net/Retrovich/article/details/133685137