Arduino应用开发——SD卡

前言

存储设备是我们在做嵌入式开发时经常用到的，常用的如flash、eeprom、SD卡、U盘等。SD卡的好处是容量大，读写速度相对较快(可以使用SDIO或SPI接口通信)。之前我也有介绍过flash的使用，那这一讲主要讲解一下SD卡的使用。
注：因为我这里只有ESP32和ESP8266，这两个MCU都是没有SDIO接口的，所以这里就以SPI接口来讲解了。

1 硬件介绍

1.1 模块简介

本文只测试了ESP32的SPI读写SD卡。
注：如果要用其他MCU，如ESP8266，实际上读写的流程是完全一样的，只有SPI的接口引脚号以及SPI库有略微区别，稍做修改即可。

硬件配置如下：

下图是我在某宝买的一个SD卡通用模组，电路非常简单，就只有几个器件，所以这里就不再具体介绍了。

1.2 硬件连接

本文主要讲解软件部分开发，硬件部分也比较简单，这里就不在这里具体介绍了。

2 软件编程和测试

版本说明：
本文测试时各软件使用的版本如下：

2.1 Arduino IDE环境搭建

Arduino开发板库安装
esp8266和esp32开发板环境搭建具体就不说了，不懂的同学可以看下我之前发布的博客。
esp8266开发入门教程(基于Arduino)——环境安装
ESP32 Arduino开发环境搭建
使用VS code搭建Arduino IDE环境

2.2 SD库API介绍

我这里只列举常用的几个函数，具体的介绍可以看下官方的SD库。

2.3 测试示例

我这里先直接用官方库提供的示例做一个测试，官方库这里基于常用的几个API做了一个封装，添加了很多调试信息，对可能出现的一些错误操作也做了提示（如：在读写之前会先判断文件是否正确打开），使得整个文件操作的流程更加完善，所以这套demo里面有很多细节都是值得参考的。
示例代码：

#include "FS.h"
#include "SD.h"
#include "SPI.h"

void listDir(fs::FS &fs, const char * dirname, uint8_t levels){
    Serial.printf("Listing directory: %s\n", dirname);

    File root = fs.open(dirname);
    if(!root){
        Serial.println("Failed to open directory");
        return;
    }
    if(!root.isDirectory()){
        Serial.println("Not a directory");
        return;
    }

    File file = root.openNextFile();
    while(file){
        if(file.isDirectory()){
            Serial.print("  DIR : ");
            Serial.println(file.name());
            if(levels){
                listDir(fs, file.path(), levels -1);
            }
        } else {
            Serial.print("  FILE: ");
            Serial.print(file.name());
            Serial.print("  SIZE: ");
            Serial.println(file.size());
        }
        file = root.openNextFile();
    }
}

void createDir(fs::FS &fs, const char * path){
    Serial.printf("Creating Dir: %s\n", path);
    if(fs.mkdir(path)){
        Serial.println("Dir created");
    } else {
        Serial.println("mkdir failed");
    }
}

void removeDir(fs::FS &fs, const char * path){
    Serial.printf("Removing Dir: %s\n", path);
    if(fs.rmdir(path)){
        Serial.println("Dir removed");
    } else {
        Serial.println("rmdir failed");
    }
}

void readFile(fs::FS &fs, const char * path){
    Serial.printf("Reading file: %s\n", path);

    File file = fs.open(path);
    if(!file){
        Serial.println("Failed to open file for reading");
        return;
    }

    Serial.print("Read from file: ");
    while(file.available()){
        Serial.write(file.read());
    }
    file.close();
}

void writeFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Writing file: %s\n", path);

    File file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }
    if(file.print(message)){
        Serial.println("File written");
    } else {
        Serial.println("Write failed");
    }
    file.close();
}

void appendFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Appending to file: %s\n", path);

    File file = fs.open(path, FILE_APPEND);
    if(!file){
        Serial.println("Failed to open file for appending");
        return;
    }
    if(file.print(message)){
        Serial.println("Message appended");
    } else {
        Serial.println("Append failed");
    }
    file.close();
}

void renameFile(fs::FS &fs, const char * path1, const char * path2){
    Serial.printf("Renaming file %s to %s\n", path1, path2);
    if (fs.rename(path1, path2)) {
        Serial.println("File renamed");
    } else {
        Serial.println("Rename failed");
    }
}

void deleteFile(fs::FS &fs, const char * path){
    Serial.printf("Deleting file: %s\n", path);
    if(fs.remove(path)){
        Serial.println("File deleted");
    } else {
        Serial.println("Delete failed");
    }
}

void testFileIO(fs::FS &fs, const char * path){
    File file = fs.open(path);
    static uint8_t buf[512];
    size_t len = 0;
    uint32_t start = millis();
    uint32_t end = start;
    if(file){
        len = file.size();
        size_t flen = len;
        start = millis();
        while(len){
            size_t toRead = len;
            if(toRead > 512){
                toRead = 512;
            }
            file.read(buf, toRead);
            len -= toRead;
        }
        end = millis() - start;
        Serial.printf("%u bytes read for %u ms\n", flen, end);
        file.close();
    } else {
        Serial.println("Failed to open file for reading");
    }


    file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }

    size_t i;
    start = millis();
    for(i=0; i<2048; i++){
        file.write(buf, 512);
    }
    end = millis() - start;
    Serial.printf("%u bytes written for %u ms\n", 2048 * 512, end);
    file.close();
}

void setup(){
    Serial.begin(115200);
    if(!SD.begin()){
        Serial.println("Card Mount Failed");
        return;
    }
    uint8_t cardType = SD.cardType();

    if(cardType == CARD_NONE){
        Serial.println("No SD card attached");
        return;
    }

    Serial.print("SD Card Type: ");
    if(cardType == CARD_MMC){
        Serial.println("MMC");
    } else if(cardType == CARD_SD){
        Serial.println("SDSC");
    } else if(cardType == CARD_SDHC){
        Serial.println("SDHC");
    } else {
        Serial.println("UNKNOWN");
    }

    uint64_t cardSize = SD.cardSize() / (1024 * 1024);
    Serial.printf("SD Card Size: %lluMB\n", cardSize);

    listDir(SD, "/", 0);
    createDir(SD, "/mydir");   // 创建一个目录/mydir
    listDir(SD, "/", 0);
    removeDir(SD, "/mydir");   // 删除/mydir目录
    listDir(SD, "/", 2);
    writeFile(SD, "/hello.txt", "Hello ");    // 打开\创建一个hello.txt文件，并在文件开头写入"Hello "
    appendFile(SD, "/hello.txt", "World!\n"); // 在hello.txt文件末尾继续写入"World!"，然后换行
    readFile(SD, "/hello.txt");               // 读取hello.txt文件的内容并打印出来
    deleteFile(SD, "/foo.txt");               // 删除foo.txt文件（提示：该目录下没有foo.txt文件，应该会提示错误）
    renameFile(SD, "/hello.txt", "/foo.txt"); // 把hello.txt文件重命名为foo.txt
    readFile(SD, "/foo.txt");                 // 读取foo.txt文件的内容并打印出来
    testFileIO(SD, "/test.txt");              // 测试文件读写速度
    Serial.printf("Total space: %lluMB\n", SD.totalBytes() / (1024 * 1024));  // 读取并打印SD卡的总容量
    Serial.printf("Used space: %lluMB\n", SD.usedBytes() / (1024 * 1024));    // 读取并打印SD卡的剩余容量
}

void loop(){

}
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207

测试结果：
通过串口打印可以看到以下信息：

如果硬件异常或者接线不对，会出现通讯异常，提示如下：

3 结束语

好了，关于如何基于Arduino使用SD卡就介绍到这里，内容不多，讲的也比较简单，如果还有什么问题，欢迎在评论区留言或者私信给我。

想了解更多Arduino的内容，可以关注一下博主，后续我还会继续分享更多的经验给大家。
esp8266基于Arduino的开发教程汇总:
https://blog.csdn.net/ShenZhen_zixian/article/details/121659482

如果这篇文章能够帮到你，就…你懂得。