NodeMcu arduino ESP8266 搭建mqtt服务(然也物联)以及使用

NodeMcu arduino ESP8266 搭建mqtt服务以及使用

本文章学习借鉴于太极创客团队，以表感谢。官网http://www.taichi-maker.com/
操作步骤：我们注册然也物联平台，申请社区版本，进行测试。

---

---

MQTT 服务搭建

当用户使用社区版MQTT服务来发布和订阅信息前，需要首先正确提供用户名和密码信息。如无法正确提供用户密码信息，则服务器将拒绝为用户提供MQTT服务。
个人用户可使用社区版MQTT服务搭建私人物联网项目。

---

一、第三方MQTT服务搭建流程

MQTT服务可以使用第三方平台，也可以自己搭建一个服务，下面我们就用第三方平台搭建一个服务，过程比较简单，申请即可。

注册平台进行申请服务

然也物联平台入口

第一步注册该平台

物联平台

公共版MQTT服务信息

此公共版MQTT服务为开放式免费服务。因此本服务主要用于个人学习测试使用。服务器会进行定期进行维护。在维护过程中，本服务将出现短暂不可用情况，且服务器会断开所有设备连接。

然也物联公共版MQTT服务端地址：test.ranye-iot.net
未加密MQTT端口：1883
SSL/TLS加密MQTT端口：8883
WebSocket端口：8080 (然也物联手机应用使用此端口)

社区版MQTT服务信息

社区版MQTT服务是面向个人用户的免费MQTT服务。与公共版MQTT服务不同的是，用户需要注册后方可使用社区版MQTT服务。
社区版MQTT服务中的用户个人主题和信息传输受到用户名和密码保护。即，A用户的个人主题只有A用户可以发布和订阅，其他人不能对该主题进行订阅和发布。

社区版需要申请，进入平台申请即可

申请通过后，平台会提供许可访问的设备id信息如下图所示

到这里我们的服务即算是搭建好了。

二、使用步骤

1.引入库

代码如下（示例）：

/**********************************************************************
项目名称/Project          : 零基础入门学用物联网
程序名称/Program name     : ranye_iot_led
团队/Team                : 太极创客团队 / Taichi-Maker (www.taichi-maker.com)
作者/Author              : CYNO朔
日期/Date（YYYYMMDD）     : 2021-10-01
程序目的/Purpose          : 
本程序旨在演示如何使用然也物联(www.ranye-iot.net)社区版实现板上LED控制。

-----------------------------------------------------------------------
本示例程序为太极创客团队制作的《零基础入门学用物联网》中示例程序。
该教程为对物联网开发感兴趣的朋友所设计和制作。如需了解更多该教程的信息，请参考以下网页：
http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/iot-tuttorial/mqtt-application/
***********************************************************************/
#include 
#include 

// 设置wifi接入信息(请根据您的WiFi信息进行修改)
const char* ssid = "taichi-maker";
const char* password = "12345678";
const char* mqttServer = "iot.ranye-iot.net";
// 如以上MQTT服务器无法正常连接，请前往以下页面寻找解决方案
// http://www.taichi-maker.com/public-mqtt-broker/

WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);

// ****************************************************
// 注意！以下需要用户根据然也物联平台信息进行修改！否则无法工作!
// ****************************************************
const char* mqttUserName = "iotuser_2";         // 服务端连接用户名(需要修改)
const char* mqttPassword = "password";          // 服务端连接密码(需要修改)
const char* clientId = "iotuser_2_id";          // 客户端id (需要修改)
const char* subTopic = "iotuser/led_kz";        // 订阅主题(需要修改)
const char* pubTopic = "iotuser/led_zt";        // 订阅主题(需要修改)
const char* willTopic = "iotuser/led_yz";       // 遗嘱主题名称(需要修改)
// ****************************************************

//遗嘱相关信息
const char* willMsg = "esp8266 offline";        // 遗嘱主题信息
const int willQos = 0;                          // 遗嘱QoS
const int willRetain = false;                   // 遗嘱保留

const int subQoS = 1;            // 客户端订阅主题时使用的QoS级别（截止2020-10-07，仅支持QoS = 1，不支持QoS = 2）
const bool cleanSession = false; // 清除会话（如QoS>0必须要设为false）

bool ledStatus = HIGH;

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);          // 设置板上LED引脚为输出模式
  digitalWrite(LED_BUILTIN, ledStatus);  // 启动后关闭板上LED
  Serial.begin(9600);                    // 启动串口通讯
  
  //设置ESP8266工作模式为无线终端模式
  WiFi.mode(WIFI_STA);
  
  // 连接WiFi
  connectWifi();
  
  // 设置MQTT服务器和端口号
  mqttClient.setServer(mqttServer, 1883);
  mqttClient.setCallback(receiveCallback);

  // 连接MQTT服务器
  connectMQTTserver();
}

void loop() {
  // 如果开发板未能成功连接服务器，则尝试连接服务器
  if (!mqttClient.connected()) {
    connectMQTTserver();
  }

   // 处理信息以及心跳
   mqttClient.loop();
   
}

// 连接MQTT服务器并订阅信息
void connectMQTTserver(){
  // 根据ESP8266的MAC地址生成客户端ID（避免与其它ESP8266的客户端ID重名）
  

  /* 连接MQTT服务器
  boolean connect(const char* id, const char* user, 
                  const char* pass, const char* willTopic, 
                  uint8_t willQos, boolean willRetain, 
                  const char* willMessage, boolean cleanSession); 
  若让设备在离线时仍然能够让qos1工作，则connect时的cleanSession需要设置为false                
                  */
  if (mqttClient.connect(clientId, mqttUserName, 
                         mqttPassword, willTopic, 
                         willQos, willRetain, willMsg, cleanSession)) { 
    Serial.print("MQTT Server Connected. ClientId: ");
    Serial.println(clientId);
    Serial.print("MQTT Server: ");
    Serial.println(mqttServer);    
    
    subscribeTopic(); // 订阅指定主题
  } else {
    Serial.print("MQTT Server Connect Failed. Client State:");
    Serial.println(mqttClient.state());
    delay(5000);
  }   
}

// 收到信息后的回调函数
void receiveCallback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message Received [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println("");
  Serial.print("Message Length(Bytes) ");
  Serial.println(length);

  if ((char)payload[0] == '1') {     // 如果收到的信息以“1”为开始
    ledStatus = LOW;
    digitalWrite(BUILTIN_LED, ledStatus);  // 则点亮LED。
  } else {
    ledStatus = HIGH;                           
    digitalWrite(BUILTIN_LED, ledStatus); // 否则熄灭LED。
  }

  pubMQTTmsg();
}

// 订阅指定主题
void subscribeTopic(){

  
  // 通过串口监视器输出是否成功订阅主题以及订阅的主题名称
  // 请注意subscribe函数第二个参数数字为QoS级别。这里为QoS = 1
  if(mqttClient.subscribe(subTopic, subQoS)){
    Serial.print("Subscribed Topic: ");
    Serial.println(subTopic);
  } else {
    Serial.print("Subscribe Fail...");
  }  
}

// 发布信息
void pubMQTTmsg(){
  char* pubMessage;
  
  if (ledStatus == LOW){
    pubMessage = "LED ON";
  } else {
    pubMessage = "LED OFF";
  }

  // 实现ESP8266向主题发布信息
  if(mqttClient.publish(pubTopic, pubMessage)){
    Serial.println("Publish Topic:");Serial.println(pubTopic);
    Serial.println("Publish message:");Serial.println(pubMessage);    
  } else {
    Serial.println("Message Publish Failed."); 
  }
}

// ESP8266连接wifi
void connectWifi(){

  WiFi.begin(ssid, password);
 
  //等待WiFi连接,成功连接后输出成功信息
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi Connected!");  
  Serial.println(""); 
}
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176

注意事项
需要配置下面的信息，每个设备只能设置一个id ，
可以手机端操作，需要下载然也物联手机端 点击下载手机端
即可以完成主题的订阅与发布，

const char* mqttUserName = “iotuser_2”; // 服务端连接用户名(需要修改)
const char* mqttPassword = “password”; // 服务端连接密码(需要修改)
const char* clientId = “iotuser_2_id”; // 客户端id (需要修改)
const char* subTopic = “iotuser/led_kz”; // 订阅主题(需要修改)
const char* pubTopic = “iotuser/led_zt”; // 订阅主题(需要修改)
const char* willTopic = “iotuser/led_yz”; // 遗嘱主题名称(需要修改)

---